home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / FAX_SSTV / VESTER_M / WXP.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1996-04-01  |  5.3 KB  |  119 lines
  1. 10  CLEAR,32768:KEY OFF:CLS:A=0:B=0:H=0:M=0:D=0:Z=0
  2. 15  OUT &H43,54:OUT &H40,0:OUT &H40,0:OUT &H3FC,0:OUT &H2FC,0
  3. 20  GOTO 1020
  4. 30  X$="system":KEY 10,X$+CHR$(13)
  5. 35  KEY 5,"LIST 1000-"+CHR$(13):KEY 4,"SAVE"+CHR$(34)+"WXP"
  6. 40  PRINT"                K3BC WEATHERFAX FOR VGA DISPLAY (640x480x16)":PRINT
  7. 50  PRINT:PRINT"   Copies WX satellite photos and maps in a 16 gray (or color) shade format."
  8. 60  PRINT"   SYSTEM CONFIGURATION can be viewed (and then modified) by hitting F5"
  9. 70  PRINT"   twice and after inserting your system parameters, just SAVE(type F4) WXP."
  10. 80  PRINT"   Requires a RAMDISK to be created in CONFIG.SYS to fit large file size. Can"
  11. 90  PRINT"   scroll the Pix, SAVE it to disk or Print in Blk/wh (not gray shades)."
  12. 95  PRINT"   F10 can be used to return to DOS prompt."
  13. 100  PRINT"      Can be configured for LSB or USB receiving.":PRINT:PRINT
  14. 110  PRINT:PRINT:PRINT
  15. 115  PRINT"      ---F5=SYS CONFIG  or BASIC --- F10=DOS---"
  16. 120  INPUT"      Do you want to copy now or later (N or L)?";X$
  17. 125  IF X$="" THEN X$="n"
  18. 127  IF X$="LIST 1000-" THEN CLS:PRINT"    F5=SYS CONFIG  F10=DOS  F2=re-RUN": END
  19. 128  IF X$="system" THEN CLS: SYSTEM
  20. 130  IF X$="N" GOTO 250
  21. 140  IF X$="n" GOTO 250
  22. 150  IF X$="L" GOTO 175
  23. 160  IF X$="l" GOTO 175
  24. 170  GOTO 120
  25. 175  PRINT:PRINT:PRINT:PRINT:PRINT:PRINT
  26. 180  SHELL "ti":PRINT:PRINT:PRINT:PRINT:PRINT:PRINT"      Now to choose your starting time (in 24 hour format)----":PRINT
  27. 190  PRINT:INPUT"  What HOUR would you like to start?";H
  28. 200  A=1
  29. 210  INPUT"           and MINUTES after the hour?";M
  30. 220  IF P$="Y" THEN D=1
  31. 230  IF P$="y" THEN D=1
  32. 240  T=0
  33. 250  PRINT:INPUT"..MINUTES of copy time (Default=14 min.)";T
  34. 260  IF T=0 THEN T=1680/120
  35. 270  B%=H
  36. 280  A%=M*256+D:D%=(120*T)
  37. 290  PRINT:INPUT"     Do you want AUTO-SYNCHRONIZING (Y or N)";S$
  38. 295  IF S$="system" THEN CLS:SYSTEM
  39. 300  IF S$="Y" THEN B=256
  40. 310  IF S$="y" THEN B=256
  41. 315  IF S$="LIST 1000-" THEN CLS:PRINT"    F5=SYS CONFIG  F10=DOS  F2=re-RUN": END
  42. 320  C%=A+B
  43. 330  DEF SEG=&H5F00:PRINT:PRINT"   ...Program loading. Check for tuning."
  44. 340  IF B=256 THEN PRINT"     .......You chose AUTO-SYNCH......."
  45. 350  BLOAD "3vgab.asm",&H100:POKE &H316,0
  46. 355  IF INF=2 THEN POKE &H3C3,2
  47. 360  LTB=INT(LT/256):LTA=LT-256*LTB:POKE &H4DE,LTA:POKE &H4DF,LTB
  48. 370  POKE &H175,GT:POKE &H4FD,SW
  49. 380  IF SB=1 THEN POKE &H19E,114:POKE &H1BA,114
  50. 390  IF SB=2 THEN POKE &H245,144:POKE &H246,144
  51. 400  IF CO=2 THEN POKE &H1D8,2:POKE &H1E5,2:POKE &H22C,2:POKE &H3C0,2:POKE &H723,2
  52. 410  IF TT=0 THEN POKE &H1D3,1
  53. 420  IF VC=2 THEN POKE &H15A,16
  54. 430  POKE &H7F0,ASC(DR$)  'RAMDISK drive-see line 1060 for designation
  55. 440  CLS:PRINT"   If FAX audio is present and you chose to copy NOW, press 'G' to start."
  56. 450  PRINT"After copy is complete, press Q or V to view and scroll with the arrows."
  57. 460  PRINT"Faster scroll with (U)p and (D)own. Page Up , Page Down and Home have"
  58. 470  PRINT"their usual function. Hit 1 thru 4 for different color palettes and hit G"
  59. 480  PRINT"to call up 16 Gray shades. Hit B to blank the whole screen."
  60. 490  PRINT"Hit S to Shrink pix vertically and X to e(X)pand it back. The pix copied"
  61. 500  PRINT"is contained in a file, 'PIX.WX', in the RAM-DISK D: and can be COPYed"
  62. 510  PRINT"to hard or floppy disk. 'SEEPIX.BAS' is used for view, scroll and (P)rint."
  63. 520  PRINT"You can Halt copying at any time by hitting H. Hit S while copying to Skip"
  64. 530  PRINT"SYNC to the left by 1/7 screen width. If you chose AUTO-SYNC and the"
  65. 540  PRINT"SYNC sigs don't occur, hit SPACEBAR to bypass AUTO-SYNC."
  66. 550  K=&H100:CALL K(A%,B%,C%,D%)
  67. 560  DEF SEG=&H4F00
  68. 570  BLOAD "vu960a.asm",&H100
  69. 580  A$=DR$+":pix.wx"
  70. 590  IF VC=2 THEN POKE 408,16
  71. 600  K=&H100:CALL K(CX%,DX%,A$)
  72. 610  PRINT:PRINT:PRINT:INPUT"    Would you like to SAVE the PIX -Yes or No (Default=N)";Z$
  73. 620  IF Z$="" THEN GOTO 640
  74. 630  IF Z$="y" THEN LI=1736:GOTO 650
  75. 640  GOTO 770
  76. 650  BLOAD "savepix.asm",&H100
  77. 651  PRINT:PRINT:PRINT:INPUT"   Save it in compressed format--y or n (Default=y)";F$
  78. 652  IF F$="" THEN F$="y"
  79. 653  IF F$="system" THEN SYSTEM
  80. 654  IF F$="y" THEN PRINT:PRINT:PRINT:INPUT"   What Path/Directory for compressed file (Default=Current)";X$:GOTO 657
  81. 655  IF F$="n" THEN GOTO 660
  82. 656  GOTO 651
  83. 657  IF X$="" THEN X$=WXP$:GOTO 660
  84. 660  PRINT:PRINT:PRINT:INPUT"    How many lines would you like to save (Default=All)";LI
  85. 670  IF LI=0 THEN LI=1736
  86. 680  LIB=INT(LI/256):LIA=LI-256*LIB:POKE &H18B,LIA:POKE &H18C,LIB
  87. 685  IF DX%<0 THEN DX!=65536+DX% ELSE DX!=DX%
  88. 690  DXB=INT(DX!/256):DXA=DX!-256*DXB:POKE &H163,DXA:POKE &H164,DXB
  89. 700  CXB=INT(CX%/256):CXA=CX%-256*CXB:POKE &H166,CXA:POKE &H167,CXB
  90. 710  POKE &H192,224:POKE &H193,1:POKE &H1B9,224:POKE &H1BA,1
  91. 720  PRINT:PRINT:PRINT:INPUT"    What File Name (Program will add Suffix---.960)";NF$
  92. 730  IF NF$="" THEN GOTO 720
  93. 740  ZF$=NF$+".960"
  94. 750  OF$=DR$+":pix.wx"
  95. 760  K=&H100:CALL K(A%,B%,OF$,ZF$)
  96. 761  IF F$="n" THEN GOTO 770
  97. 762  SHELL "wxpzip "+NF$+" "+X$+" "+DR$
  98. 770  PRINT:PRINT:PRINT:PRINT"         HIT F2 TO COPY ANOTHER PIX---HIT F10 TO GOTO DOS"
  99. 780  END
  100. 1000     '                      SYSTEM CONFIGURATION
  101. 1010     '   xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
  102. 1020  LT=13410  'Line Timing-use same value as determined by / and \ in WX prog.
  103. 1030  CO=1      'CO=1 is COM1----CO=2 is COM2
  104. 1040  TT=1      'Tone Tick-audio cue--TT=0 is OFF--TT=1 is ON
  105. 1050  GT=213    'Gross Timer-controls SYNC lock-lower value for slower computers
  106. 1060            'If too low gives a larger dead space in NON-SYNCed pix overlap
  107. 1070  DR$="d"   'RAMDISK drive designation
  108. 1080  SB=1      'Sideband to tune to--1=USB---2=LSB
  109. 1090  VC=1      'Video Card--1=VGA(640x480)---2=EGA(640x350)
  110. 1100  SW=30     'SYNC capture window (microsec). Larger for slower machines
  111. 1105  INF=1     '1=K3BC interface--2=other interface with RTS (pin 7) as +12
  112. 1107  WXP$="c:\tv\wxp\"    'Default path where WXP compressed files are saved
  113. 1110  GOTO 30
  114. 1115    '                 ------- INSTRUCTIONS -------
  115. 1120    ' To change the configuration, move cursor and type new choice and
  116. 1130    ' ENTER. Move the cursor in the clear and hit F5 to check change.
  117. 1140    ' To save the change, move cursor in the clear, hit F4, then type
  118. 1150    ' WXP and ENTER. F2 will then reRUN the program or F10 goes to DOS.
  119.